var file:FileReference = new FileReference();
file.addEventListener(Event.COMPLETE, onSaved);
stage.addEventListener(MouseEvent.CLICK, onSave);
function onSave(evt:MouseEvent):void {
	file.save("some text.\nsome more text", "actionsnippet.txt");
}

// user has saved the file... clicking again will bring up the browse window
function onSaved(evt:Event):void{
   file.removeEventListener(Event.COMPLETE, onSaved);
   stage.removeEventListener(MouseEvent.CLICK, onSave);
   stage.addEventListener(MouseEvent.CLICK, onBrowse);
}

// bring up the browse window in reponse to a mouse click
function onBrowse(evt:MouseEvent):void{
	file.browse([ new FileFilter("Text Files", "*.txt")]);
	file.addEventListener(Event.SELECT, onSelected);
}

// user has selected a file to upload from the localhost
function onSelected(evt:Event):void{
	stage.removeEventListener(MouseEvent.CLICK, onBrowse);
	file.removeEventListener(Event.SELECT, onSelected);
	file.load();
	file.addEventListener(Event.COMPLETE, onContentLoaded);
}

// the local file has been loaded, trace out the data and remove the last listener
function onContentLoaded(evt:Event):void{
	var txtContent:String  = String(evt.target.data);
	trace(txtContent);
	file.removeEventListener(Event.COMPLETE, onContentLoaded);
}

How do I load that same text into a text field using FileReference.load() and browse()?